//--Legrady trigonometric tan demo with look-up table
//--05.10.15

int XSIZE = 600; // horizontal size of screen
int YSIZE = 600; // vertical size of screen
boolean debug = false;

int MaxColors = 256; //max range of tones from black to white 0-255
float [][]clr; // declaration that clr will be a 2D array

//lookup table generator consisting of a 2Darray with 256 values of r,g,b
//the rgb values are created by placing a sinewave into the first location of the array for the RED
//then modulating this sinewave by another and putting the results into the 2nd array location for GREEN
//then modulating that for the third for the BLUE
void LUT() {
  float freq_r = 0.02;//1.3; //7.3 -- 9       -- use any number, sets color quality
  float freq_g = 2;//1.2; // 18.9 -- 29       -- use any number, sets colorquality
  float freq_b = 6;//1.7, 0.7; //9.99  -- 34      -- use any number, sets color quality
  float amp_r = 2; //1.7; //.6 -- amplitude for each sinewave, controls volume effect
  float amp_g = .95; //1.3; //0.3
  float amp_b = 1.2; //1.0; // 0.6
  clr = new float[3][MaxColors]; //initialize clr
  for (int x=0;x<MaxColors;x++) {
    clr[0][x] = MaxColors*abs(amp_r*sin((freq_r* PI)*x/MaxColors));
    clr[1][x] = MaxColors*abs(amp_g*sin((freq_g* PI)*x/MaxColors));
    clr[2][x] = MaxColors*abs(amp_b*sin((freq_b* PI)*x/MaxColors));
    // clr[2][x] = clr[1][x]*abs(amp_b*cos((freq_b* PI)*x/MaxColors));
    if (debug) println(" r[" + x + "]=" + clr[0][x] + " g=" + clr[1][x] + " b=" +clr[2][x]);
  }
}

void setup() {
  size(XSIZE,YSIZE);
  background(0); // black background
  LUT(); //activate lookup table
  CreateImage(); // call function createImage
}

void CreateImage() {
  float xfreq = 3; // how many horizontal sine waves
  float yfreq = 3; // how many vertical sine waves
  float amp = 256/2; //middle grey value

  for (int y=1;y<YSIZE;y++) {
    for (int x=1;x<XSIZE;x++) {
      // evenly spreads out tonal values per pixel between edges
      float i = PI*x*xfreq/XSIZE;
      float j = PI*y*yfreq/YSIZE;
      // calculate pixel value using sinewave
      // sine wave returns value between 0 and 1, our color range
      //is 0-255, black to white, so increase by 255
      float a = (sin(j)*sin(i)*amp)+amp;
      //keep value of a between 0 and 255
      if (a > 255) a = 255;
      else if (a < 0) a = 0;

      color c = color(clr[0][int(a)],clr[1][int(a)],clr[2][int(a)]);
      set(x,y,c);
    }
  }
  //--Saves screen to tif file, give it name of _minsec.tif
  //saveFrame("gl"+minute()+"_"+second()+".tif");
}